Las Reliquias de Tolti Aph
An interactive fiction by Graham Nelson (2005) - the Inform 7 source text
Contents
Previous
Next
Complete text
[ Los artefacos no son muy distintos de los que se encuentran en "Sorcerer's Cave", sin embargo los detalles son diferentes. El Ojo del Dios estaba maldito de forma diferente en el original: aquí es peligroso acarrearlo, pero una de las misiones del laberinto es exactamente llevarlo un buen trecho. Nuestra versión del anillo es inmensamente más poderosa, pero tiene truco: aunque el poseedor llega a ser casi inmortal en niveles más bajos, puede que emerja a niveles superiores con FUE baja, así que es algo peligroso sobrevivir a un altercado con demonios de las profundiades sólo para ser golpeado en la cabeza por un gnomo en el nivel 1.
No hay equivalente a la Varita Profética y el Mapa Encantado en el juego original de tablero: y realmente no podrían haberlo, ya que los jugadores puede siempre ver el laberinto entero extendido en el suelo.]
An artefact is a kind of thing. An artefact is esencia mágica. An artefact has a number called minimum level. The minimum level of an artefact is usually 1. Every turn when the location is the Arboleda Seca and the player carries an artefact: say "Apenas notas como desaparece [the list of artefacts carried by the player], retornados al laberinto mágicamente."; repeat with trinket running through artefacts carried by the player begin; return the trinket to the pack; end repeat.
Instead of inserting an artefact into something, say "Los artefactos del laberinto no pueden ser escondidos de ninguna de las maneras."
The Flauta Encantada is an artefact in Terra Incognita. "La Flauta Encantada, un preciado artefacto, descansa en un rincón." The description is "Cuando se toca, la Flauta Encantada apacigua a cualquier criatura hostil (salvo los no-muertos) a un estado de quietud: pero la Flauta sólo se puede tocar una vez antes de desvanecerse otra vez en el laberinto.". The Flauta Encantada is female.
[The indefinite article of the Flauta is "la".]
Musically playing is an action applying to one thing. Understand "toca [Flauta Encantada]" as musically playing. Check musically playing: if the noun is not the Flauta Encantada, say "Eso no es un instrumento musical." instead.
Carry out musically playing:
if a hostile monster is in the location
begin;
say "Mientras tocas una canción de cuna sobrenatural en la Flauta Encantada, parece como si apaciguases a [the list of hostile monsters in the location]. Ahora eres libre de andar por aquí; pero la Flauta, con su misión cumplida, desaparece.";
now all monsters in the location are indifferent;
return the Flauta Encantada to the pack;
otherwise;
say "Tocas un corto pasacalles para pasar el tiempo. Pero en la ausencia de criaturas hostiles, no hay ningún efecto salvo el apaciguamiento de tu alma cansada.";
end if.
Instead of blowing the flauta, try musically playing the flauta.
The Ojo del Dios is an artefact in Terra Incognita. "El Ojo del Dios, una funesta gema verde, te deslumbra." It has minimum level 3. The description is "Maldita y aún así preciosa, la gema el Ojo del Dios es el más extraño de todos los artefactos del laberinto."
Understand "gema" as the Ojo del Dios.
Rule for calculating combat modifiers of the player:
if the player carries the Ojo del Dios, modify to-hit roll by -2 for "llevar el Ojo del Dios";
continue the activity.
The Anillo de Poder is an artefact in Terra Incognita. "Descartado en el suelo, como si no fuera uno de los artefactos más pujantes en el laberinto, descansa el Anillo de Poder." It has minimum level 2. The description is "En el tercer nivel e inferiores del laberinto, el portador del Anillo de Poder es invulnerable a los daños (la mayoría) infligidos por otros cuando su FUE baja por debajo del doble de su propio nivel." The Anillo de Poder is wearable.
The Talismán is an artefact in Terra Incognita. "Colocado en el centro de este espacio en frente de ti está el Talismán." It has minimum level 2. The description is "Aquel que lleve el talismán no será atacado por los no-muertos." Instead of wearing the Talismán, say "Este amuleto es llevado, sin necesidad de vestirlo."
Understand "talisman" as the Talismán.
Every turn when the player carries the Talismán and an undead monster is in the location:
now all undead monsters in the location are indifferent;
say "El Talismán evita el ataque de [ list of undead monsters in the location]."
For calculating damage modifiers of the player:
let the threshold be the level of the player;
let the threshold be the threshold multiplied by 2;
let the putative strength be the strength of the player;
decrease the putative strength by the damage incurred;
if the player is wearing the Anillo de Poder and the current maze level is greater than 2 and the putative strength is less than the threshold
begin;
say ": el Anillo de Poder en tu dedo brilla con un fulgor rojo-fuego";
let the largest safe amount be the strength of the player;
decrease the largest safe amount by the threshold;
if the largest safe amount is less than 0, let the largest safe amount be 0;
change the damage incurred to the largest safe amount;
stop; [no continuar con la actividad, porque no tiene sentido.]
end if;
continue the activity.
The Alfombra Mágica is an artefact in Terra Incognita. "Enrollada frente a ti encuentras la Alfombra Mágica." It has minimum level 2. The description is "Un artefacto muy útil: permite al mago moverse, una sola vez, una posición en cualquier dirección (norte sur, este, oeste, arriba o abajo) sin importar muros o vallas. (Escribe MONTAR ALFOMBRA HACIA EL NORTE.)" The Alfombra Mágica is female.
Understand "alfombra magica" as the Alfombra Mágica.
Carpet-riding is an action applying to two visible things. Understand "monta [something preferably held] a/hacia [direction]" as carpet-riding. Check carpet-riding: if the noun is not the Alfombra Mágica, say "Eso no es algo que puedas montar." instead; if the second noun is not a direction, say "Esa no es una dirección con la que puedas ir con la alfombra." instead.
Carry out carpet-riding:
let the current position be the grid position of the location;
let the new position be the vector sum of the current position and the vector of the second noun;
if the new position is <0,0,0>, say "La alfombra es incapaz de llevarte por esa dirección, la cual te llevaría fuera del laberinto." instead;
let the destination room be the room at the new position;
let the novelty factor be 0;
if the destination room is Solid Rock
begin;
if a labyrinth room is acceptable
begin;
let the destination room be a random acceptable labyrinth room;
position the destination room at the new position;
let the novelty factor be 1;
otherwise;
say "La alfombra es incapaz de llevarte por esa dirección, la cual te llevaría fuera del laberinto." instead;
end if;
end if;
return the Alfombra Mágica to the pack;
say "La Alfombra Mágica te transporta a un lugar hacia la dirección [second noun] en el laberinto, entonces desaparece en el aire.";
let the way be the second noun;
let the reverse way be the opposite of the second noun;
if the room the way from the location is Terra Incognita
begin;
if the room the reverse way from the destination room is Terra Incognita
begin;
change the way exit of the location to the destination room;
change the reverse way exit of the destination room to the location;
otherwise;
change the way exit of the location to Solid Rock;
change the reverse way exit of the destination room to Solid Rock;
end if;
end if;
if the novelty factor is 1, draw cards for the destination room;
move the player to the destination room.
The Varita Profética is an artefact in Terra Incognita. "La Varita Profética, uno de los artefactos del Laberinto, está frente a ti." The description is "Si se agita, la Varita Profética da al mago una ligera idea de su localización en el laberinto." The Varita Profética is female.
Understand "varita profetica" as the Varita Profética.
Instead of pushing the Varita Profética: try waving the Varita Profética.
Instead of waving the Varita Profética:
say "La Varita Profética siente que ";
if the location is the Arco de Seto, say "estás en la Arcada. Vaya, qué sorpresa." instead;
if the current maze level is not 1, say "estás bajo tierra, en el nivel [current maze level] del laberinto; ";
let the current position be the grid position of the location;
let the budless position be the grid position of the Arco de Seto;
let the eastward journey be the easting part of the current position;
decrease the eastward journey by the easting part of the budless position;
let the northward journey be the northing part of the current position;
decrease the northward journey by the northing part of the budless position;
let the westward journey be 0 minus the eastward journey;
let the southward journey be 0 minus the northward journey;
if the eastward journey is 0 and the northward journey is 0
begin;
say "estás verticalmente debajo de la Arcada, ";
otherwise;
say "has viajado ";
if the eastward journey > 0, say "al este [eastward journey in words] paso[s], ";
if the westward journey > 0, say "al oeste [westward journey in words] paso[s], ";
if the northward journey > 0, say "al norte [northward journey in words] paso[s], ";
if the southward journey > 0, say "al sur [southward journey in words] paso[s], ";
end if;
let the way out be the best route from the location to the Arco de Seto;
if the way out is a direction, say "y tira de tu mano en dirección [way out].";
otherwise say "y sacude tu mano."
The Mapa Encantado is an artefact in Terra Incognita. "El Mapa Encantado, uno de los artefactos del Laberinto, yace aquí a tu disposición."
To plot line (N - a number) of room (R - a room):
if R is Solid Rock begin; say " "; stop; end if;
if R is unvisited begin; say ":::::"; stop; end if;
if R is Earthquake-damaged begin; say "#####"; stop; end if;
if R is the Isla del Lago Profundo
begin;
if N is 1, say "~~~~~";
if N is 2, say "~~O~~";
if N is 3, say "~~~~~";
stop;
end if;
if N is 1
begin;
if R exits north, say " |"; otherwise say " ";
if R is ascending, say "/ "; otherwise say " ";
end if;
if N is 2
begin;
if R exits west, say "-"; otherwise say " ";
say the map legend of R;
if R exits east, say "-"; otherwise say " ";
end if;
if N is 3
begin;
if R is descending, say " /"; otherwise say " ";
if R exits south, say "| "; otherwise say " ";
end if.
Instead of examining the Mapa Encantado:
let grid ref be the grid position of the location;
if grid ref is <0,0,0>, stop;
let L be the maze level part of the grid ref;
if L is 1, let the design be "=-=-=";
if L is 2, let the design be "-=-=-";
if L is 3, let the design be "=+=+=";
if L is 4, let the design be "=====";
if L is 5, let the design be "=+o+=";
if L is greater than 5, let the design be "#####";
say "[fixed letter spacing]+[design][design][design][design][design]+[line break]";
repeat with dN running from -1 to 1
begin;
repeat with stripe running from 1 to 3
begin;
say "#";
repeat with dE running from -2 to 2
begin;
let E be the easting part of the grid ref;
let N be the northing part of the grid ref;
let L be the maze level part of the grid ref;
let E be E plus dE;
let N be N minus dN;
let the offset ref be the spatial coordinate with maze level part L easting part E northing part N;
let the offset room be the room at the offset ref;
plot line stripe of room offset room;
end repeat;
say "#[line break]";
end repeat;
end repeat;
say "+[design][design][design][design][design]+[line break][variable letter spacing][line break]".